Oggi vediamo come configurare il bilanciamento di carico MikroTik con PCC, sfruttando due connessioni internet in modo efficace.
Questa configurazione è fondamentale per distribuire il traffico e ottimizzare le risorse di rete.
Attenzione, questa non è un’aggregazione di banda, che richiede configurazioni specifiche anche da parte dell’ISP o dispositivi remoti come il CHR per unire i due flussi in un’unica connessione e quindi uscire con un unico IP Pubblico.
Questa è semplicemente una distribuzione del carico tra 2 o più connessioni, quindi con IP differenti per ciascuna.
Alcune connessioni HTTPS, (come quelle delle banche o dei gestionali remoti), potrebbero dare problemi proprio per il fatto che potrebbe cambiare il vostro IP pubblico, quindi questa configurazione va usata con attenzione.
PCC: che cos’è e cosa fa?
Il PCC (Per Connection Classifier) è una configurazione usata su Mikrotik per bilanciare il traffico di rete tra più connessioni internet avendo 2 o più provider collegati al nostro router. Invece di usare solo una connessione alla volta, con il PCC possiamo distribuire le richieste che arrivano dagli utenti su tutte le connessioni disponibili, sfruttando al massimo tutte le risorse di rete.
Cosa fa il PCC in pratica?
Prende ogni nuova connessione (ad esempio, quando navighiamo su un sito o scarichiamo un file) e decide su quale connessione internet inviare il traffico.
Questo avviene in base a parametri che possiamo impostare, come gli indirizzi IP, le porte, i protocolli, ecc.
Se abbiamo più utenti in rete, il PCC può fare in modo che il carico venga distribuito equamente tra le connessioni, migliorando le prestazioni complessive.
Vediamo ora una configurazione di test completa su un router Mikrotik.
/interface bridge
add name=bridge-LAN
Creo un bridge chiamato “bridge-LAN” permettendo la comunicazione tra i dispositivi collegati a diverse interfacce.
/interface list
add name=WAN
Definisco una lista chiamata “WAN” che userò per raggruppare le interfacce esterne collegate ad Internet.
/ip pool
add name=dhcp_pool0 ranges=192.168.0.250-192.168.0.254
Definisco un pool DHCP con un intervallo di indirizzi IP
/ip dhcp-server
add address-pool=dhcp_pool0 interface=bridge-LAN name=dhcp1
Configuro un server DHCP associato al bridge “bridge-LAN”, utilizzando il pool definito prima.
/routing table
add disabled=no fib name=To_WAN1
add disabled=no fib name=To_WAN2
Aggiungo due tabelle di routing, “To_WAN1” e “To_WAN2”, che verranno utilizzate per instradare il traffico attraverso le due connessioni WAN.
/interface bridge port
add bridge=bridge-LAN interface=ether3
add bridge=bridge-LAN interface=ether4
Collego le interfacce “ether3” e “ether4” al bridge “bridge-LAN”.
/interface list member
add interface=ether1 list=WAN
add interface=ether2 list=WAN
Inserisco le interfacce “ether1” e “ether2” nella lista “WAN”.
/ip address
add address=10.10.0.2/24 comment=WAN1 interface=ether1 network=10.10.0.0
add address=10.100.0.2/24 comment=WAN2 interface=ether2 network=10.100.0.0
add address=192.168.0.1/24 comment=LAN interface=bridge-LAN network=192.168.0.0
Assegno gli indirizzi IP alle interfacce “ether1” e “ether2” per le connessioni WAN, e configuro l’indirizzo della rete LAN sul bridge “bridge-LAN”.
/ip dhcp-server network
add address=192.168.0.0/24 gateway=192.168.0.1
Specifico la rete DHCP che distribuisce indirizzi nella subnet 192.168.0.0/24 e imposta il gateway (192.168.0.1).
/ip dns
set servers=8.8.8.8,1.1.1.1
Definisco i server DNS pubblici (Google e Cloudflare).
Bilanciamento del traffico su WAN1 e WAN2:
/ip firewall mangle
add action=mark-connection chain=prerouting comment=”Bilancia su WAN1″ dst-address-type=!local in-interface=bridge-LAN new-connection-mark=WAN1_conn passthrough=yes per-connection-classifier=src-address-and-port:2/0
Questa regola analizza il traffico in ingresso alla rete LAN (bridge-LAN) e bilancia il traffico su WAN1. Usa un per-connection-classifier per bilanciare le connessioni in base all’indirizzo e alla porta di origine.
add action=mark-connection chain=prerouting comment=”Bilancia su WAN2″ dst-address-type=!local in-interface=bridge-LAN new-connection-mark=WAN2_conn passthrough=yes per-connection-classifier=src-address-and-port:2/1
Questa regola fa lo stesso per WAN2, bilanciando il traffico che non è instradato localmente, sempre basandosi sull’indirizzo e sulla porta di origine.
Instradamento del traffico su WAN1 e WAN2
/ip firewall mangle
add action=mark-routing chain=prerouting comment=”Instrada su WAN1″ connection-mark=WAN1_conn in-interface=bridge-LAN new-routing-mark=To_WAN1 passthrough=no
Qui viene instradato tutto il traffico con il marchio “WAN1_conn” verso la tabella di routing “To_WAN1”.
add action=mark-routing chain=prerouting comment=”Instrada su WAN2″ connection-mark=WAN2_conn in-interface=bridge-LAN new-routing-mark=To_WAN2 passthrough=no
Questa regola instrada il traffico con il marchio “WAN2_conn” verso la tabella di routing “To_WAN2”.
/ip firewall nat
add action=masquerade chain=srcnat out-interface-list=WAN
Abilito il NAT sulla lista delle interfacce WAN, permettendo ai dispositivi della rete locale di accedere a Internet.
/ip route
add check-gateway=ping disabled=no dst-address=0.0.0.0/0 gateway=10.10.0.1
add check-gateway=ping disabled=no distance=2 dst-address=0.0.0.0/0 gateway=10.100.0.1
add check-gateway=ping comment=”Route per WAN1″ disabled=no dst-address=0.0.0.0/0 gateway=10.10.0.1 routing-table=To_WAN1 suppress-hw-offload=no
add check-gateway=ping comment=”Route per WAN2″ disabled=no dst-address=0.0.0.0/0 gateway=10.100.0.1 routing-table=To_WAN2 suppress-hw-offload=no
Configuro le rotte predefinite per instradare il traffico Internet, con WAN1 come gateway principale e WAN2 come backup. Uso anche le tabelle di routing definite prima per gestire separatamente il traffico marcato per ciascuna WAN.
/system identity
set name=R1
Assegno il nome “R1” al dispositivo per identificarlo facilmente nella rete.
Questa è una configurazione base, è ovviamente possibile personalizzarla facendo il bilanciamento solo sulle connessioni UDP, su determinate porte ecc.
In sintesi, il bilanciamento di carico MikroTik con PCC è una soluzione efficiente per ottimizzare l’uso delle connessioni internet disponibili.
Se ti appassiona il mondo Mikrotik, ho anche creato un corso completo dove tratto molte configurazioni pratiche! Lo trovi su Udemy a questo indirizzo.
Hai un’azienda ed hai bisogno di supporto o assistenza? Contattami direttamente! 🚀
Lascia un commento